子どものおもちゃに曲を入れたくて、ESP32と自作NS4168アンプ基板を作った記録

# Name,   Type, SubType, Offset,   Size,     Flags
nvs,      data, nvs,     0x9000,   0x5000,
otadata,  data, ota,     0xe000,   0x2000,
app0,     app,  ota_0,   0x10000,  0x100000,
spiffs,   data, spiffs,  0x110000, 0x2F0000,

ffmpeg -i input.mp3 -ac 1 -ar 44100 -b:a 48k -map_metadata -1 00001.mp3

作業フォルダ/
├─ make_littlefs.py   ← 下のスクリプト
├─ data/
│   ├─ 00001.mp3
│   ├─ 00002.mp3
│   └─ 00003.mp3
└─ littlefs.bin       ← 実行するとできる

from littlefs import LittleFS
import os, glob
SIZE, BLOCK, PROG = 0x2F0000, 4096, 256
fs = LittleFS(block_size=BLOCK, block_count=SIZE // BLOCK,
              read_size=PROG, prog_size=PROG, disk_version=0x00020000)
for p in sorted(glob.glob("data/*.mp3")):
    with fs.open("/" + os.path.basename(p), "wb") as f:
        f.write(open(p, "rb").read())
open("littlefs.bin", "wb").write(bytes(fs.context.buffer))

py -m pip install littlefs-python
py make_littlefs.py

py -m esptool --chip esp32 --port COM5 --baud 921600 write-flash 0x110000 littlefs.bin

#include <Arduino.h>
#include <LittleFS.h>
#include <AudioFileSourceLittleFS.h>
#include <AudioFileSourceBuffer.h>
#include <AudioFileSourceID3.h>
#include <esp_partition.h>
#include <AudioGeneratorMP3.h>
#include <AudioOutputI2S.h>
constexpr int PIN_I2S_BCLK = 26;
constexpr int PIN_I2S_LRC  = 25;
constexpr int PIN_I2S_DOUT = 22;   // モジュールのSDATAへ
constexpr int PIN_NEXT_SW  = 0;    // 曲送りボタン（使わないなら -1）
AudioGeneratorMP3       *mp3  = nullptr;
AudioFileSourceLittleFS *file = nullptr;
AudioFileSourceBuffer   *buff = nullptr;
AudioFileSourceID3      *id3  = nullptr;
AudioOutputI2S          *out  = nullptr;
const char *playlist[] = { "/00001.mp3", "/00002.mp3", "/00003.mp3" };
constexpr size_t PLAYLIST_LEN = sizeof(playlist) / sizeof(playlist[0]);
size_t currentTrack = 0;
float gain = 0.3f;

void stopPlayback() {
  if (mp3 && mp3->isRunning()) mp3->stop();
  delete id3;  id3  = nullptr;
  delete buff; buff = nullptr;
  delete file; file = nullptr;
}
bool startTrack(size_t index) {
  stopPlayback();
  if (!LittleFS.exists(playlist[index])) {
    Serial.printf("ファイルがありません: %s\n", playlist[index]);
    return false;
  }
  file = new AudioFileSourceLittleFS(playlist[index]);
  buff = new AudioFileSourceBuffer(file, 8192);
  id3  = new AudioFileSourceID3(buff);
  if (!mp3) mp3 = new AudioGeneratorMP3();
  out->SetGain(gain);
  bool ok = mp3->begin(id3, out);
  Serial.printf("再生: %s (%s)\n", playlist[index], ok ? "OK" : "失敗");
  return ok;
}

void listFiles() {
  Serial.println("--- LittleFS 内のファイル ---");
  File root = LittleFS.open("/");
  for (File f = root.openNextFile(); f; f = root.openNextFile()) {
    Serial.printf("  %-16s %8u bytes\n", f.name(), (unsigned)f.size());
  }
  Serial.printf("使用量: %u / %u bytes\n",
                (unsigned)LittleFS.usedBytes(), (unsigned)LittleFS.totalBytes());
}

void setup() {
  Serial.begin(115200);
  delay(300);
  if (PIN_NEXT_SW >= 0) pinMode(PIN_NEXT_SW, INPUT_PULLUP);
  // 曲の領域が想定どおりかを表示する
  const esp_partition_t *p = esp_partition_find_first(
      ESP_PARTITION_TYPE_DATA, ESP_PARTITION_SUBTYPE_DATA_SPIFFS, NULL);
  if (p) {
    Serial.printf("曲の領域: 開始=0x%06X  サイズ=%u bytes\n",
                  (unsigned)p->address, (unsigned)p->size);
  } else {
    Serial.println("曲の領域が見つかりません。Partition Scheme を Custom に");
  }
  out = new AudioOutputI2S();
  out->SetBuffers(12, 1024);
  out->SetPinout(PIN_I2S_BCLK, PIN_I2S_LRC, PIN_I2S_DOUT);
  out->SetRate(44100);
  out->SetGain(gain);
  if (!LittleFS.begin(false)) {
    Serial.println("LittleFS のマウントに失敗");
    return;
  }
  listFiles();
  startTrack(currentTrack);
  Serial.println("n=次の曲 / p=前の曲 / s=停止 / +,-=音量");
}

void loop() {
  if (mp3 && mp3->isRunning()) {
    if (!mp3->loop()) {
      mp3->stop();
      currentTrack = (currentTrack + 1) % PLAYLIST_LEN;
      startTrack(currentTrack);
    }
  }
  if (Serial.available()) {
    char c = Serial.read();
    if (c == 'n') {
      currentTrack = (currentTrack + 1) % PLAYLIST_LEN;
      startTrack(currentTrack);
    } else if (c == 'p') {
      currentTrack = (currentTrack + PLAYLIST_LEN - 1) % PLAYLIST_LEN;
      startTrack(currentTrack);
    } else if (c == 's') {
      stopPlayback();
    } else if (c == '+' || c == '-') {
      gain += (c == '+') ? 0.1f : -0.1f;
      gain = constrain(gain, 0.0f, 2.0f);
      if (out) out->SetGain(gain);
      Serial.printf("gain=%.1f\n", gain);
    }
  }
  if (PIN_NEXT_SW >= 0 && digitalRead(PIN_NEXT_SW) == LOW) {
    delay(30);
    if (digitalRead(PIN_NEXT_SW) == LOW) {
      currentTrack = (currentTrack + 1) % PLAYLIST_LEN;
      startTrack(currentTrack);
      while (digitalRead(PIN_NEXT_SW) == LOW) delay(10);
    }
  }
}

曲の領域: 開始=0x110000  サイズ=3080192 bytes
--- LittleFS 内のファイル ---
  00001.mp3          681866 bytes
  00002.mp3          763525 bytes
  00003.mp3          742992 bytes
再生: /00001.mp3 (OK)

out = new AudioOutputI2S(0, AudioOutputI2S::INTERNAL_DAC);

E (326) esp_littlefs: ... lfs.c:1383:error: Corrupted dir pair at {0x1, 0x0}
E (327) esp_littlefs: mount failed,  (-84)

constexpr int PIN_AMP_SD = 27;   // 基板の SD へ
void setAmp(bool on) {
  if (on) {
    pinMode(PIN_AMP_SD, INPUT);      // Hi-Z。R1のプルアップでCTRL = 3.3V
  } else {
    digitalWrite(PIN_AMP_SD, LOW);   // 先にLowを用意してから出力にする
    pinMode(PIN_AMP_SD, OUTPUT);     // CTRL = 約0.3V
  }
}